10  ON NER GOTO 1160
20  HOME 
30  VTAB 10: PRINT  TAB( 15);"HAMMURABI"
40  PRINT  TAB( 15);"---------"
50  VTAB 15: PRINT "Voulez-vous les regles du jeu (O/N) ";: INPUT XX$
60  IF  LEFT$ (XX$,1) = "N" THEN 180
70  REM  REGLES DU JEU 
80  HOME 
90  VTAB 4: PRINT "  Dans ce jeu vous donnez les instruction a Hammurabi ,l'administrateur de la ville de Sumer,pour gerer la ville."
100  PRINT "Celle ci a au depart 100 habitants,1000 acres de terre,et 2800 boisseaux de ble en reserve."
110  PRINT "Vous pouvez acheter ou vendre des terres aux etats voisin en echange de boisseaux de ble (le prix varie entre 17 et 26 boisseaux par acre) "
120  PRINT "Vous devez aussi vous servir du ble pour nourrir votre population (chaque habitant a besoin de 20 boisseaux par an pour vivre),ainsi que pour ensemencer la culture de l'annee suivante (1 boisseau permet d'ensemencer 2 acres)."
130  VTAB 23: INPUT "Pour continuer enfoncer la touche RETURN";XX$
140  HOME : VTAB 4
150  PRINT : PRINT "  Vous vous apercevrez qu'un certain nombre de personnes ne peuvent entretenir qu'une certaine superficie de terre.Vous aurez aussi a faire face a contre l'imprevisible:la peste ,les rats ,les mauvaises recoltes."
160  PRINT : PRINT : PRINT "Vous devez donc essayer de mener a bien cette dificille tache pendant une dure de 10 ans.Bonne chance!!"
170  VTAB 23: INPUT "Pour continuer enfoncer la touche RETURN";XX$
180 P = 100:S = 2800:A = 1000
190 Z = 1:MO = 0:MT = 0:P1 = 0
200  HOME 
210  PRINT "Vous possedez ";A;" acres de terre"
220  PRINT S;" boisseaux en reserve 
230  PRINT "est la population est de ";P;" habitants"
240 PV =  INT (10 *  RND (1)) + 17
250  PRINT : PRINT "Les ventes de terres se font au prix de ";PV;" boisseaux par acres "
260  PRINT : PRINT "Combien d' acres de terrain voulez-vous acheter ";: GOSUB 1120
270  INPUT D
280  CALL  - 958
290  IF D = 0 THEN 330
300  IF D * PV > S THEN  PRINT "Vous n'avez que ";S;" boisseaux de ble en reserve ": GOSUB 1140: GOTO 270
310  IF D < 0 THEN  PRINT "Ne racontez pas n'importe quoi !!Vous delirez !!": GOSUB 1140: GOTO 270
320 S = S - PV * D:A = A + D
330  PRINT : PRINT "Combien d'acres de terrain voulez-vous vendre ";: GOSUB 1120
340  INPUT D
350  CALL  - 958
360  IF D = 0 THEN 410
370  IF A < D THEN  PRINT "Vous ne possedez que ";A;" acres de terre, recommencez.": GOSUB 1140: GOTO 340
380  IF D > 0 THEN S = S + PV * D:A = A - D: GOTO 410
390  PRINT "Ne racontez pas n'importe quoi !!": GOSUB 1140
400  GOTO 340
410  PRINT : PRINT "Combien de boisseaux de ble reservez vous a la nouriture de votre peuple";: GOSUB 1120
420  INPUT D
430  CALL  - 958
440  IF D < 0 THEN  PRINT "Ne racontez pas n'importe quoi !!Vous delirez !!": GOSUB 1140: GOTO 420
450  IF D <  = S THEN S = S - D:MO = P -  INT (D / 20): GOTO 470
460  PRINT "Vous n'avez que ";S;" boisseaux de ble ne reserve": GOSUB 1140: GOTO 420
470  IF MO < 0 THEN MO = 0
480 MT = MT + MO:P1 = P1 + 100 * MO / P
490  PRINT : PRINT "Combien d'acres de terre voulez vous ensemencer  ";
500  GOSUB 1120
510  INPUT TC
520  CALL  - 958
530  IF TC < 0 THEN  PRINT "Ne racontez pas n'importe quoi!!Vous delirez !!": GOSUB 1140: GOTO 510
540  IF A < TC THEN  PRINT "Vous ne possedez que ";A;" acres de terre": GOSUB 1140: GOTO 510
550  IF TC / 10 > P THEN  PRINT "Vous n'avez que ";P;" personnes pour les traveaux des champs": GOSUB 1140: GOTO 510
560  IF TC / 2 > S THEN  PRINT "Vous n'avez que ";S;" boisseaux de ble en reserve": GOSUB 1140: GOTO 510
565  PRINT : PRINT : INPUT "Voulez vous changer quelque chose (O/N) ? ";A$
566  IF  LEFT$ (A$,1) = "O" THEN 200
570  HOME 
580  PRINT  TAB( 15);"HAMMURABI"
590  PRINT : PRINT  TAB( 3);"J'ai l'honneur de vous informer": PRINT  TAB( 3);"des faits suivants:"
600  PRINT : PRINT "Durant la ";Z;: IF Z = 1 THEN  PRINT "ere";: GOTO 620
610  PRINT "eme";
620  PRINT " annee de votre regne:"
630  IF MO > .45 * P THEN  PRINT MO;" personnes sont mortes de faim par votre faute.En raison de cette extreme incompetence vous avez ete jete dehors et declare plaie nationale.": GOTO 1040
640  PRINT : PRINT : PRINT : IF MO = 0 THEN  PRINT "Personne n'est mort de faim ,et ";: GOTO 670
650  IF MO = 1 THEN  PRINT "Une personne est morte de faim,et ";: GOTO 670
660  PRINT MO;" personnes sont mortes de faim,et ";
670 P = P - MO
680  GOSUB 1100
690 D =  INT (C * (20 * A + S) / P / 100 + 1)
700  IF D = 0 THEN  PRINT "Personne n'est venu a la ville.": GOTO 730
710  IF D = 1 THEN  PRINT "Une personne est venue a la ville.": GOTO 730
720  PRINT D;" personnes sont venues a la ville."
730 P = P + D
740  IF  INT (10 * (2 *  RND (1) - .2)) <  = 0 THEN P =  INT (P / 2): PRINT " Une horrible peste a sevie et la moitie de la population est morte"
750  PRINT : PRINT  TAB( 5);"De sorte que la population actuelle ": PRINT  TAB( 5);"est de ";P;" personnes ."
760  GOSUB 1110
770  PRINT : PRINT " Vous avez moissonne ";C;" boisseaux par acres"
780 TC = TC * C
790  GOSUB 1110
800 R = 0
810  IF  INT (C / 2) = C / 2 THEN R =  INT (S / C)
820  PRINT "Les rats ont mange ";R;" boisseaux "
830 S = S + TC - R
840  PRINT "Vous avez maintenant ";S;" boisseaux de ble en reserve."
850  PRINT : PRINT "La ville possede maintenant ";A;" acres."
855  PRINT : PRINT : PRINT : PRINT " Pressez ' RETURN ' pour continuer ": GET ALEX$
860 Z = Z + 1
870  FOR I = 1 TO 10000: NEXT I
880  IF Z < 11 THEN 200
900 P1 =  INT (P1 * 10) / 100
910  HOME : VTAB 5: PRINT "Pendant les 10 annees ou vous avez gerer la ville ";P1;"% de la population est mort de faim chaque annee en moyenne,soit un total de ";MT;" deces ."
920 L =  INT (A / P * 100) / 100: PRINT : PRINT : PRINT " Vous avez debute avec 10 acres  par personne pour finir avec ";L;" acres par personne."
930  IF P1 > 33 OR L < 7 THEN  PRINT "Votre incompetence est devenue proverbiale ,pour cette raison le peuple ( enfin ce qui  reste apres votre performance ) excede vous a jete dehors et vous a creve": GOTO 950
940  GOTO 960
950  PRINT "l'oeil droit.Maintanant il pend le long de joue et vous avez l'air encore plus con(ne) que d'habitude.": GOTO 1040
960  IF P1 > 10 OR L < 9 THEN  PRINT : PRINT : PRINT "Votre performance riduculise Neron et Ivan le terrible,le peuple ou du moins ce qu'il en reste,";: GOTO 980
970  GOTO 990
980  PRINT " pense que vous etes un chef detestable et souhaite ardement vous voir crever la geule ouverte.": GOTO 1040
990  IF P1 > 3 OR L < 10 THEN  PRINT : PRINT : PRINT "Vos resultats aurait pu etre meilleurs mais comme vous avez essaye de faire de votre mieux il n'y a que ";: GOTO 1010
1000  GOTO 1020
1010  PRINT  INT (P * .8 *  RND (1));" personnes qui veulent vous assassiner.": GOTO 1040
1020  PRINT : PRINT : PRINT "Votre performance est remarquable. Disraeli ,Charlemagne et Jefferson ne sont que du pipi de chat a cote de vous."
1030  PRINT "Le peuple en liesse a erige un monument a votre image qui fera date dans l'histoire de la laideur !!!!!!!"
1040  VTAB 22: PRINT "Voulez vous rejouer (O/N) ";: GOSUB 1120
1050  INPUT XX$
1060  IF  LEFT$ (XX$,1) = "O" THEN 180
1065  PRINT : PRINT " BYE-BYE ..."
1070  CALL  - 958
1094  END 
1100 C =  INT ( RND (1) * 5) + 1
1110  RETURN 
1120 PH =  PEEK (36) + 1:VP =  PEEK (37) + 1
1130  RETURN 
1140  HTAB PH: VTAB VP: CALL  - 868
1150  RETURN 
1160  PRINT "Mauvaise entree recomencez "
1170  HTAB PH: VTAB VP: CALL  - 868